Этот пример использует функцию APIGetBillProp и выводит различные параметры тарификации. Скрипт запускается из командной строки в директории scripts.

 

 cscript.exe billprop.vbs APIPassword ObjectType ObjectID /sn:ServerName

 

 ObjectID - опциональный параметр.

 ServerName - имя сервера - необязательный параметр - задается при запуске скрипта с удаленного компьютера.

 

---

Set Args = WScript.Arguments.Unnamed

If Args.Count < 2 Then

 WScript.Echo "??? usage: cscript.exe billprop.vbs APIPassword ObjectType ObjectID /sn:ServerName"        

 WScript.Quit        

End If

 

APIPass = Args(0)

ObjType = Args(1)

If Args.Count >= 3 Then

 ObjID = Args(2)

End If

 

If WScript.Arguments.Named.Exists("sn") Then

 ServName = WScript.Arguments.Named.Item("sn")

 Set Srv = CreateObject("TrafInsp.TrafInspAdmin",ServName)

Else

 Set Srv = CreateObject("TrafInsp.TrafInspAdmin")

End If

Srv.APILogon(APIPass)

BillData = Srv.ApiGetBillProp(ObjType, ObjID)

 

If Not IsArray(BillData) Then

 WScript.Echo "Нет данных"        

 WScript.Quit        

End If

 

If IsArray(BillData(0)) Then

 For I = 0 To UBound(BillData, 1)

         Data = BillData(I)

         WScript.Echo Data(0) & Chr(9) & Data(1) & Chr(9) & Data(2) & Chr(9) & Data(3) & Chr(9) & Data(4) & Chr(9) & Data(5) & Chr(9) & Data(6) & Chr(9) & Data(7)

 Next

Else

 WScript.Echo "Объект" & Chr(9) & BillData(0)

 WScript.Echo "GUID" & Chr(9) & BillData(1)

 WScript.Echo "Группа" & Chr(9) & BillData(2)

 WScript.Echo "По умолчанию" & Chr(9) & BillData(3)

 WScript.Echo "Способ тариф. трафика" & Chr(9) & BillData(4)

 WScript.Echo "Цена за трафик" & Chr(9) & BillData(5)

 WScript.Echo "Предопл. трафик" & Chr(9) & BillData(6)

 WScript.Echo "Цена за время" & Chr(9) & BillData(7)

End If

 

 

 

---

Текущая страница справки: help.smart-soft.ru/index.html?apidemogetbill.htm

Сайт разработчиков Traffic Inspector