Изменение настроек прокси сервера

Previous pageReturn to chapter overviewNext page

 

Файл - setproxyconfig.vbs

 

Задача - изменять настройки прокси сервера, а конкретно режима каскадирования. В консоли они доступны в разделе настроек Прокси-сервера.

 

Этим скриптом можно, например, переключать прокси сервер по расписанию на разные вышестоящие сервера, включать или отключать эти опции.

 

Функции через API, используемые этим скриптом, доступны начиная со сборки 1752.

 


 

Dim argsNamed, DOM

 

Sub Apply(Attr)

   If argsNamed.Exists(Attr) Then

      DOM.documentElement.setAttribute Attr, argsNamed.Item(Attr)

   End If

End Sub

 

Set argsNamed = WScript.Arguments.Named

Set argsUnnamed = WScript.Arguments.Unnamed

 

If argsUnnamed.Count = 0 Then

   WScript.Echo "Утилита изменения настроек прокси сервера. Синтаксис - "   

   WScript.Echo "cscript.exe setproxyconfig.vbs APIPassword /AttrName:Value [/AttrName2:Value2]..."   

   WScript.Echo "AttrName - имя атрибута"   

   WScript.Echo "Value - значение"   

   WScript.Echo "Описание атрибутов находится в файле schema.xsd, элемент ProxyConfig"   

   WScript.Echo "Обрабатываются атрибуты - "   

   WScript.Echo "ProxyFwEnabled (0, 1)"

   WScript.Echo "ProxyFwHost"

   WScript.Echo "ProxyFwPort"

   WScript.Echo "ProxyFwUser"

   WScript.Echo "ProxyFwPass"

   WScript.Echo "SocksFwEnabled (0, 1)"

   WScript.Echo "SocksFwHost"

   WScript.Echo "SocksFwPort"

   WScript.Echo "SocksFwUser"

   WScript.Echo "SocksFwPass"

   WScript.Echo "SocksFwMode5 (0, 1)"

   WScript.Echo "Примеры - "

   WScript.Echo "cscript.exe setproxyconfig.vbs 12345678 /ProxyFwEnabled:1 /ProxyFwHost:10.1.1.1 /ProxyFwPort:8080"

   WScript.Echo "cscript.exe setproxyconfig.vbs 12345678 /ProxyFwEnabled:0"

   WScript.Quit   

End If

 

Set Srv = CreateObject("TrafInsp.TrafInspAdmin")

Srv.APILogon(argsUnnamed(0))

 

Set DOM = WScript.CreateObject("Msxml2.DOMDocument.4.0")

DOM.loadXML("<ProxyConfig/>")

If Dom.parseError.errorCode <> 0 Then

   Err.Raise 51, "LoadXml", Dom.parseError.reason

End If

 

Apply("ProxyFwEnabled")

Apply("ProxyFwHost")

Apply("ProxyFwPort")

Apply("ProxyFwUser")

Apply("ProxyFwPass")

Apply("SocksFwEnabled")

Apply("SocksFwHost")

Apply("SocksFwPort")

Apply("SocksFwUser")

Apply("SocksFwPass")

Apply("SocksFwMode5")

 

Srv.APISetServerConfig 20, DOM.xml, unassigned, unassigned

 

 

 


Текущая страница справки: help.smart-soft.ru/index.html?apidemosetproxyconfig.htm

Сайт разработчиков Traffic Inspector