Аутентификация через API для пользователя.

 

 XMLData = Srv.APILogon2(UserName, Password, FromIP)

 

Аргументы

 

 UserName

 Строковое выражение задающее логин пользователя программы (заведенного в разделе Администрирование консоли).

 

 Password

 Строковое выражение определяющее пароль соответствующего пользователя программы.

 

 FromIP

 Пустой параметр, зарезервирован для будущего использования.

 

 

Возвращаемое значение

 

 XML строка с данными авторизации. Формат данных см. в описании функции APILogon. Получаемые права - в соответствии с правами пользователя.

 

 

Пример использования

 

 Скрипт выводит информацию о группе и уровне доступа пользователя.

 

---

Set Args = WScript.Arguments

If Args.Count <> 2 Then

   WScript.Echo "??? usage: cscript.exe adm_level.vbs UserLogin UserPass /sn:ServerName"

   WScript.Quit

End If

 

UserL = Args(0)

UserP = Args(1)

 

If WScript.Arguments.Named.Exists("sn") Then

   ServName = WScript.Arguments.Named.Item("sn")

   Set Srv = CreateObject("TrafInsp.TrafInspAdmin", ServName)

Else

   Set Srv = CreateObject("TrafInsp.TrafInspAdmin")

End If

 

Set AdmLD = WScript.CreateObject("Msxml2.DOMDocument.4.0")

AdmLD.loadXML Srv.APILogon2(UserL, UserP, "")

 

Set DocEl = AdmLD.documentElement

Set currNode = DocEl.selectSingleNode("AdminItem")

AdmName = currNode.getAttribute("DisplayName")

Set currNode = DocEl.selectSingleNode("AdminGroupItem")

AdmGroup = currNode.getAttribute("DisplayName")

AdmLevel = currNode.getAttribute("Level")

 

WScript.Echo "Пользователь: " & AdmName

Select Case AdmLevel

   Case 0  AdmLevelInfo = "Администратор"

   Case 1  AdmLevelInfo = "Менеджер"

   Case 2  AdmLevelInfo = "Кассир"

End Select

WScript.Echo " группа: " & AdmGroup & ", уровень доступа " & AdmLevel & ": " & AdmLevelInfo

 

---

Текущая страница справки: help.smart-soft.ru/index.html?apilogon2.htm

Сайт разработчиков Traffic Inspector